ESP32: Wifi (Basic)

update: 09.07.2019

Concept: Internet Wifi Network

Wifi_Basic_01

Device 1. Access Point (AP) or Hotspot or RouterDevice 2. Station or Node

Access Point (แอคเซสพอยต์ AP) (สถานีแม่ข่าย) คืออุปกรณ์ที่มีหน้าที่ในการกระจายสัญญาณ wireless (ไวร์เลส) เป็นอุปกรณ์พื้นฐานตัวหนึ่งที่สามารถสร้างเครือข่ายไร้สายจากระบบเครือข่าย Lan (แลน) ได้ง่ายที่สุด Access Point ทำหน้าที่กระจายสัญญาณออกไปยังเครื่องลูกข่าย (Station) ที่อยู่ในรัศมีการกระจายสัญญาณโดยรอบ

Station (เครื่องลูกข่าย) หรือ สถานีผู้ใช้ (Client Station) ซึ่งก็คืออุปกรณ์คอมพิวเตอร์ (Desktop, Laptop) ที่มีอุปกรณ์ Client Adapter เพื่อใช้รับส่งข้อมูลผ่าน Wi-Fi

ESP32 สามารถทำงานในโหมด Wifi ได้ 3 Mode คือ

  • AP (Access Point)
  • STA (Station)
  • AP+STA

Wifi Simple: Project 1. Access Point Mode

Problem

จงเขียนโปรแกรมให้ ESP32 ทำงานใน Access Point Mode คือสร้างสัญญาณ Wifi ทำตัวเป็น Router โดยให้ผู้เรียนกำหนด ชื่อ wifi ssid และ wifi password ของตัวเอง

Wifi_Basic_03

Circuit

No.

Program

//ESP32_Wifi_AP_Project1.ino

#include <WiFi.h>

#define WIFI_AP_NAME "TE_0_Phatiphat" //your Wifi ID
#define WIFI_AP_PASS "0819174058" //your Password, > 7 numbers

void setup() {
  Serial.begin(115200);
  
  WiFi.mode(WIFI_AP);
  WiFi.softAP(WIFI_AP_NAME, WIFI_AP_PASS);

  Serial.print("IP address: ");
  Serial.println(WiFi.softAPIP());
}

void loop() { }


Result

Press RESET and see the serial monitor and use your mobile phone connecting to Wifi, so that you will see a new Wifi router name ……….

Phatiphat

Description

Wifi_Basic_02


Wifi Simple: Project 2. Access Point Mode and Server Mode

Problem

จงเขียนโปรแกรมให้ ESP32 ทำงานใน Access Point Mode คือสร้างสัญญาณ Wifi ทำตัวเป็น Router โดยให้ผู้เรียนกำหนด ชื่อ wifi ssid และ wifi password ของตัวเอง  พร้อมทั้งให้ ESP32 ทำงานเป็น Server มี html code (web page) มีปุ่มกดควบคุมการทำงานของ LED 1 หลอดที่ต่อที่ขา GPIO15

Circuit

Wifi_Basic_04

Program

//ESP32_Wifi_AP_Project2_Server.ino

#include <WiFi.h>

#define WIFI_AP_NAME "TE_0_Phatiphat" 
#define WIFI_AP_PASS "0819174058" 

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Variable to store the current output state
String LED0State = "off";

// Assign output variables to GPIO pin
const int LED0 = 15;

void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(LED0, OUTPUT);

  // Set outputs to LOW
  digitalWrite(LED0, LOW);


  // Connect to Wi-Fi network with SSID and password
  Serial.println("Setting AP (Access Point)…");
  
  // Remove the password parameter, if you want the AP (Access Point) to be open
  WiFi.mode(WIFI_AP); //Be careful!!!
  WiFi.softAP(WIFI_AP_NAME, WIFI_AP_PASS);

  IPAddress IP = WiFi.softAPIP();
  Serial.print("AP IP address: ");
  Serial.println(IP);
  
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
            
            // turns the GPIOs on and off
            if (header.indexOf("GET /LED0/on") >= 0) {
              Serial.println("LED0 on");
              LED0State = "on";
              digitalWrite(LED0, HIGH);
              
            } else if (header.indexOf("GET /LED0/off") >= 0) {
              Serial.println("LED0 off");
              LED0State = "off";
              digitalWrite(LED0, LOW);
            } 
            
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #FF0000; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #C0C0C0;}</style></head>");
            
            // Web Page Heading
            client.println("<body><h1>TE-KMUTNB</h1>");
            client.println("<body><h2>ESP32 Web Server</h2>");
            
            // Display current state, and ON/OFF buttons for GPIO 0 
            client.println("<p>LED0 - State " + LED0State + "</p>");
            
            // If the LED0State is off, it displays the ON button       
            if (LED0State=="off") {
              client.println("<p><a href=\"/LED0/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/LED0/off\"><button class=\"button button2\">OFF</button></a></p>");
            } 
               
            client.println("</body></html>");
            
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

 

Result

1). Press RESET

2). See the serial monitor.

Phatiphat 007

 

 

 

 

 

3). Connect your device to ESP32 wifi…

Phatiphat 008

Phatiphat 009

4). After your device connecting to your ESP32 wifi then go to a web browser and then type: your ESP32 IP address.

Phatiphat 010.JPG

Note: you see LED0 – State off. It means Initial state = LED0 OFF

5). PRESS ON button so that it will show as follow. This means a LED0 = ON.

Phatiphat 011

then press OFF button, so that LED0 = OFF, shown as follow:

Phatiphat 012

 

Description

Wifi_Basic_05

สรุป

โปรแกรมค่อนข้างซับซ้อน  เนื่องจากผู้เรียนต้องมีความเข้าใจ html code ระดับหนึ่ง  แต่ในภายหลังจะง่ายขึ้นถ้าต่อ ESP32 เข้าระบบ Cloud….